#version 450
#extension GL_EXT_buffer_reference : require

#include "hex_common.glsl"

layout(location = 0) flat out vec4 color;

void main() {
  uint hex_index = pc.context.points.p[gl_InstanceIndex].hex;
  uint vertex_index = pc.context.points.p[gl_InstanceIndex].vertex;
  Region region = pc.context.regions[pc.context.points.p[gl_InstanceIndex].region];
  float raise = pc.context.points.p[gl_InstanceIndex].offset;
  if(hex_index != 0xFFFFFFFF) {
    color = pc.context.points.p[gl_InstanceIndex].color;
    gl_PointSize = pc.context.points.p[gl_InstanceIndex].size;

    vec2 region_qr = vec2(region.q, region.r);

    vec4 region_pos = vec4(0, 0, 0, 0);
    region_pos.x = (region_qr.x+region_qr.y/2)*region_width - region_qr.y*x/2;
    region_pos.z = 0.75*region_qr.y*region_height + 0.25*region_qr.y*z + 0.5*region_qr.x*z;

    float radius = 0;
    float ring = 0;
    int side = 0;
    if(hex_index != 0) {
      radius = floor(0.5 + sqrt(12*hex_index-3)/6);
      ring = hex_index - (3*radius*radius - 3*radius + 1);
      side = int(floor(ring/radius));
    } 

    vec4 position = vertices[vertex_index]
      + (starts[side]*radius)
      + (direction[side]*(ring-(radius*side)))
      + region_pos;

    position.y = region.hexes[hex_index].heights[vertex_index-1] + region.y + raise;

    gl_Position = pc.context.proj * pc.context.view * position;
  } else {
    gl_Position = vec4(0, 0, 0, 0);
    color = vec4(0, 0, 0, 0);
  }
}